Remplacer la fonction SI par une formule logique

Introduction aux valeurs logiques

Outre des valeurs alphanumériques, des formules et des nombres, Excel permet d’entrer dans les cellules d’une feuille de calcul les valeurs logiques VRAI ou FAUX. Ces valeurs peuvent être utilisées pour effectuer des opérations. VRAI étant égal à 1 et FAUX à 0.

Les opérateurs de comparaisons

1 – Prenons un premier cas simple

Nous avons une liste de données (plage A5:B5) dont la première colonne contient le sexe de la personne (F ou M) et dans l’autre colonne une formule qui attribuera une prime de 50€ à toutes les personnes de sexe féminin.

La formule sera =SI(A5="F";50;0)

Nous allons maintenant remplacer cette formule par la formule =(A5="F") * 50

Nous pouvons constater que nous obtenons le même résultat.

2 – Utilisons un ET en ajoutant une condition

Pour obtenir la prime de 50€, il faut à la fois être une femme et habiter la commune de Champignac. La plage de données (A5:C5) contient en colonne A, le sexe, colonne B la localité et en colonne C, la formule

La formule sera =SI(ET(A5="F";B5="Champignac");50;0)

Cette formule peut être remplacée par =(A5="F") * (B5="Champignac") * 50

Soit si toutes les conditions sont remplies 1 * 1 * 50 donnera 50. La multiplication de tests logiques est équivalent à un ET

3 – Utilisons un OU en utilisant les mêmes conditions que dans le cas n° 2

La formule sera =SI(OU(A5="F";B5="Champignac");50;0)

Pour utiliser les tests logiques en donnant 50€ pour toutes personnes répondant à au moins une des conditions, nous allons utiliser l’addition des conditions mais en ajoutant un test logique englobant ces additions, comme nous le montre la formule ci-dessous.

=((A5="F") + (B5="Champignac") > 0) * 50

Ce qui se traduit si les deux conditions sont remplies par

Etape 1 (sans la comparaison globale)  : (1+1) * 50 donnerait  100 (Ce qui ne serait pas exact)

Etape 2 (avec la comparaison globale) : (1+1>0) * 50 ce qui donne VRAI et donc se traduit par 1 * 50